Deepseek 快速部署，实现Word高效办公。部署前需申请Deepseek账号，以便导入API-key （必须）。

第一步：注册账号，并申请专有的API-key 。

第二步：打开Word，点击文件，打开Word选项，进入信任中心，“宏设置”中选择：启用所有宏和信任对VBA工程对象模型的访问，最后点击确定。

第三步：此时在Word界面就有《开发工具》选项卡，点卡之后便将Visual Basic ，新建模块，并把Deepseek代码复制进模块中。此过程相关较复制，也是很关键的一步。

第四步，复制代码，关键点：将从Deepseek中创建的API-key，替换代码中的”替换为你的API-key"和“请填写API key”两处均需替换！

Sub DeepSeekV3()
    Dim api_key As String
    Dim inputText As String
    Dim response As String
    Dim regex As Object
    Dim matches As Object
    Dim originalSelection As Object

    api_key = "替换为你的API Key"
    If api_key = "" Then
        MsgBox "请填写API Key。"
        Exit Sub
    ElseIf Selection.Type <> wdSelectionNormal Then
        MsgBox "请先选中文本。"
        Exit Sub
    End If

    ' 保存原始选中文本
    Set originalSelection = Selection.Range.Duplicate
    inputText = Replace(Replace(Replace(Replace(Replace(Selection.Text, "\", "\\"), vbCrLf, ""), vbCr, ""), vbLf, ""), Chr(34), "\""")

    response = CallDeepSeekAPI(api_key, inputText)

    If Left(response, 5) <> "Error" Then
        Set regex = CreateObject("VBScript.RegExp")
        With regex
            .Global = True
            .MultiLine = True
            .Pattern = """content"":\s*""([\s\S]*?)"""
        End With

        If regex.Test(response) Then
            response = regex.Execute(response)(0).SubMatches(0)
            ' 处理转义字符（如 \n 转为换行）
            response = Replace(response, "\n", vbCrLf)
            ' 插入新行并显示结果
            Selection.Collapse Direction:=wdCollapseEnd
            Selection.TypeParagraph
            Selection.TypeText Text:=response
            originalSelection.Select
        Else
            MsgBox "解析响应失败。", vbExclamation
        End If
    Else
        MsgBox response, vbCritical
    End If
End Sub

Function CallDeepSeekAPI(api_key As String, inputText As String) As String
    Dim API As String
    Dim SendTxt As String
    Dim Http As Object
    Dim status_code As Integer
    Dim response As String

    API = "https://api.deepseek.com/chat/completions"
    SendTxt = "{""model"":""deepseek-chat"",""messages"":[{""role"":""user"",""content"":""" & inputText & """}],""stream"":false}"

    Set Http = CreateObject("MSXML2.XMLHTTP")
    With Http
        .Open "POST", API, False
        .setRequestHeader "Content-Type", "application/json"
        .setRequestHeader "Authorization", "Bearer " & api_key
        .send SendTxt
        status_code = .Status
        response = .responseText
    End With

    If status_code = 200 Then
        CallDeepSeekAPI = response
    Else
        CallDeepSeekAPI = "Error: " & status_code & " - " & response
    End If
    Set Http = Nothing
End Function

第五步：将新建的模块导入“开发工具”中。

第六步，在Word界面就有添加的Deepseek按钮

第七步，测试

以上就是我个人设置Deepseek接入Word的过程，虽说第一次设置有点点复杂，但是设置完成后还是很好用。